Julia Sets

Code (see the Mandelbrot set code to see how this works, if you’re interested):

gr =
    Table[
      ListDensityPlot[
        Table[-Length[
          FixedPointList[ #^2 + a + b I &, x + I y, 35,
            SameTest->(Abs[#2] > 2.0 &) ]],
       {y, -1.1, 1.1, 2.2/35},{x, -1.1, 1.1, 2.2/35}],
        Mesh->False, Frame->False, Axes->False,
        AspectRatio->1, DisplayFunction->Identity ],
     {a, -2.0, 1.0, 1/3.}, {b, -1.0, 1.0, 1/3.} ];
 
Show[ GraphicsArray[ Transpose[gr] ] ]

In Mathematica 3.0 we can make the iteration function about five times faster by compiling it. Here’s the new version (at least the new version from 1996, before GraphicsArray became obsolete):

cJulia = 
  Compile[{{c, _Complex}, {k, _Complex}}, 
    -Length[
      FixedPointList[#^2 + k &, c, 35, SameTest -> (Abs[#2] > 2.0 &)]
      ]];
 
Show[
  GraphicsArray[
    Table[
      ListDensityPlot[
        Table[ cJulia[x + y I, a + b I],
          {y, -1.1, 1.1, 0.0628}, {x, -1.1, 1.1, 0.0628}],
        Mesh -> False, Frame -> False, Axes -> False,
        AspectRatio -> 1, DisplayFunction -> Identity],
    {b, -1.0, 1.0, 1/3.}, {a, -2.0, 1.0, 1/3.} ]]];

Designed and rendered using Mathematica 2.2 and 3.0 for Apple Macintosh and (much later) 7.0 for Microsoft Windows.

[ home ] || [ 1996-??-?? ]